home *** CD-ROM | disk | FTP | other *** search
/ Apple II Magazines (DO) / Softdisk Magazette Volume 1, No. 06 (1982-02)(Softdisk)(Side B).zip / Softdisk Magazette Volume 1, No. 06 (1982-02)(Softdisk)(Side B).do / SAT.TEST.bas < prev    next >
BASIC Source File  |  1996-12-24  |  8KB  |  210 lines
  1. 10  DIM CA$(27),W$(27,20),CW$(27,30)
  2. 20  DIM C(27),CC$(30)
  3. 30  TEXT : HOME 
  4. 40 A$ = "SAT / PSAT": GOSUB 3000
  5. 50  PRINT 
  6. 60 A$ = "VERBAL PREPARATION": GOSUB 3000
  7. 70  PRINT : PRINT 
  8. 80 A$ = "SYNONYMS TEST": GOSUB 3000
  9. 90  PRINT 
  10. 100 A$ = "PROGRAMMED BY LARRY SELTZER"
  11. 110  GOSUB 3000
  12. 120  IF I = 1  THEN 160
  13. 130  VTAB 14
  14. 140  INPUT "INSTRUCTIONS (Y/N) ===>";AN$
  15. 150  IF  LEFT$(AN$,1) = "Y"  THEN 4000
  16. 160  VTAB 16
  17. 170  PRINT "HOW MANY POSSIBLE CATEGORIES DO YOU"
  18. 180  PRINT : INPUT "WANT (2-20)";N1
  19. 190  IF N1 <2  OR N1 >20  OR N1 < > INT(N1)  THEN  PRINT  CHR$(7): GOTO 30
  20. 200  FOR X = 1 TO N1
  21. 210  READ CA$(X)
  22. 220 N = 0
  23. 230 N = N +1
  24. 240  READ W$(X,N)
  25. 250  IF W$(X,N) = "X"  THEN 270
  26. 260  GOTO 230
  27. 270  NEXT X
  28. 280  CALL  -936
  29. 290  FOR X = 1 TO N1
  30. 300  VTAB X
  31. 310  PRINT X;"."; TAB( 6);CA$(X)
  32. 320  NEXT X
  33. 330  VTAB 21
  34. 340  PRINT "---------------------------------------"
  35. 350  POKE 34,21
  36. 360 CT =  INT( RND(8) *N1) +1
  37. 370 W =  INT( RND(8) *17) +1
  38. 380  IF W$(CT,W) = ""  OR W$(CT,W) = "X"  THEN 370
  39. 390  HOME 
  40. 400  VTAB 22
  41. 410  PRINT W$(CT,W): PRINT 
  42. 420  INPUT "WHAT CATEGORY IS THIS FROM ";A$
  43. 430  IF A$ = "L"  THEN 630
  44. 440 A =  VAL(A$)
  45. 450  CALL  -936
  46. 460  IF A = CT  THEN 500
  47. 470  PRINT "SORRY, THAT IS INCORRECT.
  48. 480  PRINT "THE CORRECT CHOICE IS: ";CT
  49. 490  GOTO 510
  50. 500  PRINT "THAT IS CORRECT."
  51. 510  VTAB CT: HTAB 1
  52. 520  INVERSE 
  53. 530  PRINT CT"."; TAB( 6);CA$(CT)
  54. 540  VTAB 24: PRINT "PRESS ANY KEY TO CONTINUE";
  55. 550  NORMAL 
  56. 560  GET A$
  57. 570  VTAB CT: HTAB 1
  58. 580  PRINT CT"."; TAB( 6);CA$(CT)
  59. 590  CALL  -936
  60. 600 C(CT) = C(CT) +1
  61. 610 CW$(CT,C(CT)) = W$(CT,W)
  62. 620  GOTO 360
  63. 630  INPUT "LIST WHICH CATEGORY ";N
  64. 640  IF N <1  OR N >N1  THEN  PRINT  CHR$(7);: GOTO 680
  65. 650  IF C(N) < >0  THEN 710
  66. 660  PRINT : INVERSE : PRINT "NO WORDS IN THIS CATEGORY"
  67. 670  NORMAL 
  68. 680  PRINT : PRINT "PRESS ANY KEY TO CONTINUE";
  69. 690  GET A$
  70. 700  GOTO 390
  71. 710  IF C(N) = 1  THEN 850
  72. 720 CC$(1) = CW$(N,1):NC = 1
  73. 730  FOR H1 = 1 TO C(N)
  74. 740  FOR H2 = 1 TO NC
  75. 750  IF CW$(N,H1) = CC$(H2)  THEN 780
  76. 760  NEXT H2
  77. 770 NC = NC +1:CC$(NC) = CW$(N,H1)
  78. 780  NEXT H1
  79. 790 C(N) = NC
  80. 800  FOR H = 1 TO C(N):CW$(N,H) = CC$(H): NEXT H
  81. 810  FOR J = 1 TO C(N) -1: FOR I = J +1 TO C(N)
  82. 820  IF CW$(N,J) <CW$(N,I)  THEN 840
  83. 830 G$ = CW$(N,J):CW$(N,J) = CW$(N,I):CW$(N,I) = G$
  84. 840  NEXT I: NEXT J
  85. 850  INVERSE 
  86. 860  TEXT : CALL  -936
  87. 870  PRINT CA$(N): PRINT : PRINT 
  88. 880  NORMAL 
  89. 890  FOR H = 1 TO C(N)
  90. 900  PRINT CW$(N,H)
  91. 910  NEXT H
  92. 920  PRINT : PRINT "PRESS ANY KEY TO CONTINUE";
  93. 930  GET A$
  94. 940  CALL  -936
  95. 950  FOR X = 1 TO N1
  96. 960  VTAB X
  97. 970  PRINT X;"."; TAB( 6);CA$(X)
  98. 980  NEXT X
  99. 990  PRINT "---------------------------------------"
  100. 1000  POKE 34,21
  101. 1010  GOTO 390
  102. 2000  DATA  "SLOW, LAZY, LIFELESS"
  103. 2010  DATA  SLUGGISH,LETHARGIC,LACKADAISACAL,LANGUID,COMATOSE,TORPID,PHLEGMATIC,LISTLESS,X
  104. 2020  DATA  "REPETITIVE; OVERLY WORDY; TALKATIVE"
  105. 2030  DATA  PROLIX,TAUTOLOGIC,VERBOSE,BOLUBLE,LOQUACIOUS,REDUNDANT,GARRULOUS,GLIB,CIRCUMLOCUTORY,EXPATIATE,X
  106. 2040  DATA "SHORT, PRECICE; TO THE POINT"
  107. 2050  DATA  TERSE,PITHY,SUCCINCT,CONCISE,LACONIC,EPIGRAMMATIC,TACITURN,SENTENTIOUS,APHORISTIC,CURT,X
  108. 2060  DATA  HAPPY
  109. 2070  DATA SANGUINE,BLITHE,EXULTANT,JOCUND,FELICITY,JUBILANT,BEATIFIC,CONVIVIAL,X
  110. 2080  DATA  SAD
  111. 2090  DATA   DEJECTED,LUGUBRIOUS,DOLOROUS,MELANCHOLY,DOWNCAST,DISCONSOLATE,DESPONDENT,ELEGY,DIRGE,LAMENT,LACHRYMOSE,SATURNINE,MOROSE,X
  112. 2100  DATA  WORLDLY
  113. 2110  DATA  SOPHISTICATED,URBANE,SUAVE,COSMOPOLITAN,POLISHED,REFINED,X
  114. 2120  DATA  QUARRELSOME
  115. 2130  DATA  CHOLERIC,IRASCIBLE,BELLIGERENT,BELLACOSE,PUGNACIOUS,TRUCULENT,CONTENTIOUS,X
  116. 2140  DATA  TOP
  117. 2150  DATA  APEX,APOGEE,ZENITH,PEAK,CREST,ACME,PINNACLE,SUMMIT,PLATEAU,CULMINATION,X
  118. 2160  DATA  BOTTOM 
  119. 2170  DATA  PLAIN,CANYON,VALLEY,PERIGEE,BASE,GORGE,NADIR,ROOT,TROUGH,X
  120. 2180  DATA  "BAD; HARMFUL; DEADLY"
  121. 2190  DATA  INIMICAL,NOXIOUS,LETHAL,MIASMIC,DELETERIOUS,REPUGNANT,FATAL,EGREGIOUS,NEFARIOUS,INVIDIOUS,BALEFUL,BANEFUL,HEINOUS,MALIGNANT,VIRULENT,ODIOUS,X
  122. 2200  DATA "FEARFUL; COWARDLY"
  123. 2210  DATA  TIMOROUS,CRAUEN,PUSILLANIMOUS,DASTARDLY,FECKLESS,X
  124. 2220  DATA "UNREHEARSED; SPUR OF THE MOMENT"
  125. 2230  DATA  SPONTANEOUS,IMPROMPTU,EXTEMPERANEOUS,FORTUITOUS,ADVENTITIOUS,X
  126. 2240  DATA  STINGY
  127. 2250  DATA  NIGGARDLY,PARSIMONIOUS,PENURIOUS,FRUGAL,THRIFTY,X
  128. 2260  DATA  "TEMPORARY, NOT LASTING"
  129. 2270  DATA  EPHERMAL,TRANSIENT,FLEETING,EVANESCENT,X
  130. 2280  DATA "REDUCTION IN SIZE, LESSENING"
  131. 2290  DATA  CURTAIL,ABRIDGEMENT,WANING,ABATEMENT,ATTRITION,X
  132. 2300  DATA  PEACEFUL
  133. 2310  DATA  SERENE,PACIFIC,HALCYON,PLACID,TRANQUIL,X
  134. 2320  DATA  VERY LARGE IN SIZE
  135. 2330  DATA  LEVIATHAN,PRODIGIOUS,MAMMOTH,GARGANTUAN,TITANIC,COLLOSSAL,X
  136. 2340  DATA  VERY SMALL IN SIZE
  137. 2350  DATA  INFINITESIMAL,MITE,LILLIPUTION,EXIGOUS,SCINTILLA,X
  138. 2360  DATA  TO SCOLD
  139. 2370  DATA  VITUPERATE,BERATE,UPBRAID,REVILE,REBUKE,FLAY,EXCORCIATE,CHASTISE,CASTIGATE,REPROVE,REPROACH,X
  140. 2380  DATA  BEGINNER
  141. 2390  DATA  TYRO,TENDERFOOT,NOVICE,NEOPHYTE,ACOLYTE,X
  142. 2400  DATA  STUBBORN
  143. 2410  DATA  REFRACTORY,RECALCITRANT,TENACIOUS,OBDURATE,ADAMANT,RESOLUTE,INTRACTABLE,PERTINACIOUS,DUCTILE,X
  144. 2420  DATA  TO SOOTHE
  145. 2430  DATA  PLACATE,PACIFY,MOLLIFY,ALLAY,ASSUAYE,PALLIATE,APPEASE,PROPITIATE,X
  146. 2440  DATA "HONOR; AWARD"
  147. 2450  DATA  ACCOLADE,LAURAL,PLAUDITS,RECONGNITION,ENCOMIUM,LAUDITORY,PANEGYRIC,PAEAN,EULOGY,X
  148. 2460  DATA  "BAD-DOER"
  149. 2470  DATA  TRANSGRESSOR,MALEFACTOR,FELON,MISCREANT,X
  150. 2480  DATA  IRRITABLE
  151. 2490  DATA  PETULANT,WASPISH,CANTAKEROUS,QUERULOUS,BILIOUS,FRACTIUOS,X
  152. 2500  DATA  IMPOVERISHED
  153. 2510  DATA  IMPECUNIOUS,INDIGENT,DESTITUTE,PENURY,X
  154. 2520  DATA  "MORALLY LAX; NO SELF RESTRAINT"
  155. 2530  DATA  WANTON,HEDONISTIC,PROFLIGATE,DISSOLUTE,LASCIVIOUS,LICENTIOUS,LIBERTINE,X
  156. 2540  DATA  UNEMOTIONAL
  157. 2550  DATA  STAID,STOLID,SEDATE,IMPASSIVE,PHLEGMATIC,GRAVE,SOMBER,X
  158. 3000  PRINT  TAB( 20 -( LEN(A$)/2));A$
  159. 3010  RETURN 
  160. 4000  HOME 
  161. 4010 I = 1
  162. 4020  VTAB 5
  163. 4030  PRINT "THE NUMBER OF VOCABULARY WORDS YOU NEED"
  164. 4040  PRINT : PRINT "TO KNOW FOR YOUR SAT TEST IS QUITE"
  165. 4050  PRINT : PRINT "LARGE.  RATHER THAN LEARN THE EXACT"
  166. 4060  PRINT : PRINT "DEFINITION OF EACH WORD, WHICH WOULD"
  167. 4070  PRINT : PRINT "TAKE A GREAT DEAL OF TIME, YOU COULD"
  168. 4080  PRINT : PRINT "LEARN TO GROUP WORDS TOGETHER AND"
  169. 4090  PRINT : PRINT "JUST REMEMBER ONE DEFINITION."
  170. 4100  GOSUB 5000
  171. 4110  HOME 
  172. 4120  PRINT : PRINT : PRINT "FOR EXAMPLE, YOU COULD GROUP THE WORDS:"
  173. 4130  PRINT : PRINT "ZENITH, PEAK, CREST, ACME, APOGEE,"
  174. 4140  PRINT : PRINT "PINNACLE, SUMMIT, PLATEAU AND"
  175. 4150  PRINT : PRINT "CULMINATION TOGETHER AND REMEMBER THAT"
  176. 4160  PRINT : PRINT "THEY ALL MEAN 'TOP'"
  177. 4170  PRINT : PRINT : PRINT "NOT ONLY IS THIS EASIER TO REMEMBER,"
  178. 4180  PRINT : PRINT "BUT IT GIVES YOU ALMOST ALL THE"
  179. 4190  PRINT : PRINT "INFORMATION THE SATS WILL EVER ASK YOU"
  180. 4200  PRINT : PRINT "TO SUPPLY ABOUT A WORD."
  181. 4210  GOSUB 5000
  182. 4220  HOME 
  183. 4230  PRINT "IN THIS TEST, YOU WILL SEE FROM 2 TO 20"
  184. 4240  PRINT : PRINT "CATEGORIES PRINTED AT THE TOP OF THE"
  185. 4250  PRINT : PRINT "SCREEN.  A WORD WILL BE PRINTED ON THE"
  186. 4260  PRINT : PRINT "BOTTOM OF THE SCREEN, AND YOU MUST TYPE"
  187. 4270  PRINT : PRINT "IN THE NUMBER OF THE CATEGORY TO WHICH"
  188. 4280  PRINT : PRINT "THIS WORD BELONGS."
  189. 4290  PRINT : PRINT : PRINT "IF YOU WANT A LIST OF SOME OF THE WORDS"
  190. 4300  PRINT : PRINT "THAT YOU'VE ALREADY PUT IN A CATEGORY,"
  191. 4310  PRINT : PRINT "TYPE 'L' INSTEAD OF A NUMBER.  THEN"
  192. 4320  PRINT : PRINT "TYPE IN THE NUMBER OF THE CATEGORY."
  193. 4330  GOSUB 5000
  194. 4340  HOME 
  195. 4350  PRINT "ONE MORE THING....": PRINT 
  196. 4360  PRINT "ONCE YOU'VE STARTED THE TEST, THE ONLY"
  197. 4370  PRINT : PRINT "WAY TO STOP IT IS TO PRESS CTRL-C OR"
  198. 4380  PRINT : PRINT "RESET."
  199. 4390  PRINT : PRINT : PRINT "IF YOU REALLY WANT TO DO WELL ON THE"
  200. 4400  PRINT : PRINT "SATS, YOU SHOULD CONTINUE PRACTICING"
  201. 4410  PRINT : PRINT "THIS TEST UNTIL YOU ARE ABLE TO PLACE"
  202. 4420  PRINT : PRINT "EVERY WORD IN THE CORRECT CATEGORY."
  203. 4430  GOSUB 5000
  204. 4440  GOTO 30
  205. 5000  INVERSE 
  206. 5010  VTAB 22: PRINT "PRESS THE SPACE BAR TO CONTINUE"
  207. 5020  GET A$
  208. 5030  IF A$ < >" "  THEN 5020
  209. 5040  NORMAL 
  210. 5050  RETURN